ΟΙΚΟΝΟΜΙΚΕΣ ΣΥΝΑΡΤΗΣΕΙΣ

Οι οικονομικές συναρτήσεις χρησιμοποιούνται για συνήθεις υπολογισμούς, οι οποίοι σχετίζονται με χρήματα (αποσβέσεις, δάνεια κτλ). Οι κυριότερες συναρτήσεις της κατηγορίας αυτής είναι οι παρακάτω :

DB	DDB	FV	IPMT	IRR
ISPMT	MIRR	NPER	NPV	PMT
PPMT	PV	RATE	SLN	SYD
VDB

DB(cost;salvage;life;period;month)

Αποδίδει την απόσβεση παγίου σε καθορισμένη περίοδο με τη μέθοδο του σταθερά φθίνοντος υπολοίπου.

Cost   είναι το αρχικό κόστος του πάγιου.

Salvage    είναι η τελική αξία του παγίου, αφού ολοκληρωθεί η απόσβεσή του (μερικές φορές αναφέρεται ως υπολειμματική αξία του παγίου).

Life είναι ο συνολικός χρόνος απόσβεσης του παγίου (μερικές φορές αναφέρεται ως ωφέλιμος χρόνος ζωής του παγίου).

Period    είναι η περίοδος για την οποία θέλετε να υπολογίσετε την απόσβεση. Η περίοδος πρέπει να χρησιμοποιεί τις ίδιες μονάδες με το όρισμα life.

Month    είναι ο αριθμός των μηνών του πρώτου έτους. Εάν παραλειφθεί ο αριθμός των μηνών, θεωρείται ίσος με 12.

Παρατηρήσεις

· Η μέθοδος του σταθερά φθίνοντος υπολοίπου υπολογίζει την απόσβεση με σταθερό ρυθμό. Η συνάρτηση DB χρησιμοποιεί τους εξής τύπους για τον υπολογισμό της απόσβεσης σε μια χρονική περίοδο:

(cost - συνολική απόσβεση προηγούμενων περιόδων) * rate

όπου:

rate = 1 - ((salvage / cost) ^ (1 / life)), στρογγυλοποιημένο σε τρία δεκαδικά ψηφία

· Η απόσβεση για την πρώτη και την τελευταία περίοδο αποτελεί ειδική περίπτωση. Για την πρώτη περίοδο, η συνάρτηση DB χρησιμοποιεί τον τύπο:

cost * rate * month / 12

· Για την τελευταία περίοδο, η συνάρτηση DB χρησιμοποιεί τον τύπο:

((cost - συνολική απόσβεση προηγούμενων περιόδων) * rate * (12 - month)) / 12

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	1.000.000	Αρχικό κόστος
3	100.000	Υπολειμματική αξία
4	6	Διάρκεια ζωής σε έτη
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=DB(A2;A3;A4;1;7)	Απόσβεση κατά το πρώτο έτος, με υπολογισμό μόνο 7 μηνών (186.083,33)
7	=DB(A2;A3;A4;2;7)	Απόσβεση κατά το δεύτερο έτος (259.639,42)
8	=DB(A2;A3;A4;3;7)	Απόσβεση κατά το τρίτο έτος (176.814,44)
9	=DB(A2;A3;A4;4;7)	Απόσβεση κατά το τέταρτο έτος (120.410,64)
10	=DB(A2;A3;A4;5;7)	Απόσβεση κατά το πέμπτο έτος (81.999,64)
11	=DB(A2;A3;A4;6;7)	Απόσβεση κατά το έκτο έτος (55.841,76)
12	=DB(A2;A3;A4;7;7)	Απόσβεση κατά το έβδομο έτος, με υπολογισμό μόνο 5 μηνών (15.845,10)

DDB(cost;salvage;life;period;factor)

Αποδίδει την απόσβεση παγίου σε συγκεκριμένη χρονική περίοδο, χρησιμοποιώντας τη μέθοδο του διπλά φθίνοντος υπολοίπου ή κάποια άλλη μέθοδο που εσείς καθορίζετε.

Cost    είναι το αρχικό κόστος του παγίου.

Salvage    είναι η τελική αξία του παγίου, αφού ολοκληρωθεί η απόσβεσή του (μερικές φορές αναφέρεται ως υπολειμματική αξία του παγίου).

Life    είναι ο συνολικός χρόνος απόσβεσης του παγίου (μερικές φορές αναφέρεται ως ωφέλιμος χρόνος ζωής του παγίου).

Period    είναι η περίοδος για την οποία θέλετε να υπολογίσετε την απόσβεση. Η περίοδος πρέπει να χρησιμοποιεί τις ίδιες μονάδες με το όρισμα life.

Factor    είναι ο ρυθμός με τον οποίο φθίνει το υπόλοιπο. Εάν παραλειφθεί το όρισμα factor, θεωρείται ίσο με 2 (μέθοδος του διπλά φθίνοντος υπολοίπου).

Προσοχή :  Και τα πέντε ορίσματα πρέπει να είναι θετικοί αριθμοί.

Παρατηρήσεις

• Η μέθοδος του διπλά φθίνοντος υπολοίπου υπολογίζει την απόσβεση με επιταχυνόμενο ρυθμό. Η απόσβεση είναι υψηλότατη κατά την πρώτη περίοδο και μειώνεται καθώς οι περίοδοι διαδέχονται η μία την άλλη. Η συνάρτηση DDB χρησιμοποιεί τον ακόλουθο τύπο, για να υπολογίσει την απόσβεση για μια περίοδο: ((cost-salvage) - συνολική απόσβεση από προηγούμενες περιόδους (periods)) * (factor/life)
• Αλλάξτε το όρισμα factor, εάν δεν θέλετε να χρησιμοποιήσετε τη μέθοδο του διπλά φθίνοντος υπολοίπου.
• Χρησιμοποιήστε τη συνάρτηση VDB, εάν θέλετε να μεταβείτε στη μέθοδο σταθερής απόσβεσης, όταν η απόσβεση είναι μεγαλύτερη από τον υπολογισμό του φθίνοντος υπολοίπου.

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	2400	Αρχικό κόστος
3	300	Υπολειμματική αξία
4	10	Διάρκεια ζωής σε έτη
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=DDB(A2;A3;A4*365;1)	Η απόσβεση της πρώτης ημέρας. Το Microsoft Excel θεωρεί αυτόματα ότι το όρισμα factor είναι 2. (1,32)
7	=DDB(A2;A3;A4*12;1;2)	Η απόσβεση του πρώτου μήνα (40,00)
8	=DDB(A2;A3;A4;1;2)	Η απόσβεση του πρώτου έτους (480,00)
9	=DDB(A2;A3;A4;2;1,5)	Η απόσβεση του δεύτερου έτους, χρησιμοποιώντας την τιμή 1,5 για το όρισμα factor, αντί για τη μέθοδο του διπλά φθίνοντος υπολοίπου. (306,00)
10	=DDB(A2;A3;A4;10)	Η απόσβεση του δέκατου έτους. Το Microsoft Excel θεωρεί αυτόματα ότι το όρισμα factor είναι 2 (22,12)

Σημείωση :  Τα αποτελέσματα στρογγυλοποιούνται σε δύο δεκαδικά ψηφία.

FV(rate;nper;pmt;pv;type)

Αποδίδει τη μελλοντική αξία μιας επένδυσης με βάση περιοδικές, σταθερές πληρωμές και σταθερό επιτόκιο.

Rate    είναι το επιτόκιο ανά περίοδο.

Nper    είναι ο συνολικός αριθμός των περιόδων πληρωμής μιας προσόδου.

Pmt    είναι η πληρωμή που καταβάλλεται σε κάθε περίοδο και δεν μπορεί να αλλάξει κατά τη διάρκεια της προσόδου. Συνήθως, το όρισμα pmt περικλείει αρχικό κεφάλαιο και επιτόκιο, αλλά όχι τέλη ή φόρους. Εάν παραλειφθεί το όρισμα pmt, πρέπει να συμπεριλάβετε το όρισμα pv.

Pv   είναι η παρούσα αξία ή το εφάπαξ ποσό που αντιπροσωπεύει μια σειρά μελλοντικών πληρωμών σε τρέχουσες τιμές. Εάν παραλειφθεί το όρισμα pv, θεωρείται ίσο με 0 και πρέπει να συμπεριληφθεί το όρισμα pmt.

Type    είναι ο αριθμός 0 ή 1 και επισημαίνει πότε πρέπει να καταβάλλονται οι πληρωμές. Εάν παραλειφθεί το όρισμα type, θεωρείται ίσο με 0.

Type	Πληρωμές
0	Στο τέλος της περιόδου
1	Στην αρχή της περιόδου

Παρατηρήσεις

• Βεβαιωθείτε για τη συνέπεια των μονάδων που χρησιμοποιούνται στις τιμές των ορισμάτων rate και nper. Εάν κάνετε μηνιαίες πληρωμές για ένα τετραετές δάνειο με 12 τοις εκατό ετήσιο επιτόκιο, χρησιμοποιήστε το 12%/12 για το όρισμα rate και το 4*12 για το όρισμα nper. Εάν κάνετε ετήσιες πληρωμές για το ίδιο δάνειο, χρησιμοποιήστε το 12% για το όρισμα rate και το 4 για το όρισμα nper.
• Για όλα τα ορίσματα, τα ποσά που καταβάλλετε, όπως οι καταθέσεις που κάνετε, αποδίδονται με αρνητικούς αριθμούς, ενώ τα ποσά που εισπράττετε, όπως οι επιταγές μερισμάτων, αποδίδονται με θετικούς αριθμούς.

Παράδειγμα 1 :

	A	B
1	Δεδομένα	Περιγραφή
2	6%	Ετήσιο επιτόκιο
3	10	Αριθμός πληρωμών
4	-200	Ποσό πληρωμής
5	-500	Παρούσα αξία
6	1	Η πληρωμή πρέπει να καταβάλλεται στην αρχή της περιόδου (βλέπε παραπάνω)
7	Τύπος	Περιγραφή (αποτέλεσμα)
8	=FV(A2/12; A3; A4; A5; A6)	Μελλοντική αξία μιας επένδυσης με τους παραπάνω όρους (2581,40)

Σημείωση   Το ετήσιο επιτόκιο διαιρείται δια του 12, επειδή υπολογίζεται σε μηνιαία βάση.

Παράδειγμα 2 :

	A	B
1	Δεδομένα	Περιγραφή
2	12%	Ετήσιο επιτόκιο
3	12	Αριθμός πληρωμών
4	-1000	Ποσό πληρωμής
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=FV(A2/12; A3; A4)	Μελλοντική αξία μιας επένδυσης με τους παραπάνω όρους (12.682,50)

Σημείωση   Το ετήσιο επιτόκιο διαιρείται δια του 12, επειδή υπολογίζεται σε μηνιαία βάση.

Παράδειγμα 3 :

	A	B
1	Δεδομένα	Περιγραφή
2	11%	Ετήσιο επιτόκιο
3	35	Αριθμός πληρωμών
4	-2000	Ποσό πληρωμής
5	1	Η πληρωμή πρέπει να καταβάλλεται στην αρχή του έτους (βλέπε παραπάνω)
6	Τύπος	Περιγραφή (αποτέλεσμα)
7	=FV(A2/12; A3; A4;; A5)	Μελλοντική αξία μιας επένδυσης με τους παραπάνω όρους (82.846,25)

Σημείωση   Το ετήσιο επιτόκιο διαιρείται δια του 12, επειδή υπολογίζεται σε μηνιαία βάση.

Παράδειγμα 4 :

	A	B
1	Δεδομένα	Περιγραφή
2	6%	Ετήσιο επιτόκιο
3	12	Αριθμός πληρωμών
4	-100	Ποσό πληρωμής
5	-1000	Παρούσα αξία
6	1	Η πληρωμή πρέπει να καταβάλλεται στην αρχή του έτους (βλέπε παραπάνω)
7	Τύπος	Περιγραφή (αποτέλεσμα)
8	=FV(A2/12; A3; A4; A5; A6)	Μελλοντική αξία μιας επένδυσης με τους παραπάνω όρους (2301,40)

Σημείωση   Το ετήσιο επιτόκιο διαιρείται δια του 12, επειδή υπολογίζεται σε μηνιαία βάση.

IPMT(rate;per;nper;pv;fv;type)

Αποδίδει την καταβολή τόκων μιας επένδυσης, σε μια δεδομένη χρονική περίοδο, με βάση περιοδικές, σταθερές πληρωμές και σταθερό επιτόκιο.

Rate   είναι το επιτόκιο ανά περίοδο.

Per    είναι η περίοδος για την οποία θέλετε να υπολογίσετε τον τόκο και πρέπει να είναι μεταξύ 1 και nper.

Nper   είναι ο συνολικός αριθμός των περιόδων πληρωμής μιας προσόδου.

Pv    είναι η παρούσα αξία ή το εφάπαξ ποσό που αντιπροσωπεύει μια σειρά μελλοντικών πληρωμών σε τρέχουσες τιμές.

Fv    είναι η μελλοντική αξία ή το υπόλοιπο που θέλετε να έχετε μετά την καταβολή της τελευταίας πληρωμής. Εάν παραλειφθεί το όρισμα fv, θεωρείται ίσο με 0 (η μελλοντική αξία ενός δανείου, για παράδειγμα, είναι 0).

Type    είναι ο αριθμός 0 ή 1 και επισημαίνει πότε πρέπει να καταβάλλονται οι πληρωμές. Εάν παραλειφθεί το όρισμα type, θεωρείται ίσο με 0.

Type	Πληρωμές
0	Στο τέλος της περιόδου
1	Στην αρχή της περιόδου

Παρατηρήσεις

• Βεβαιωθείτε για τη συνέπεια των μονάδων που χρησιμοποιούνται στις τιμές των ορισμάτων rate και nper. Εάν κάνετε μηνιαίες πληρωμές για ένα τετραετές δάνειο με 12 τοις εκατό ετήσιο επιτόκιο, χρησιμοποιήστε το 12%/12 για το όρισμα rate και το 4*12 για το όρισμα nper. Εάν κάνετε ετήσιες πληρωμές για το ίδιο δάνειο, χρησιμοποιήστε το 12% για το όρισμα rate και το 4 για το όρισμα nper.
• Για όλα τα ορίσματα, τα ποσά που καταβάλλετε, όπως οι καταθέσεις που κάνετε, αποδίδονται με αρνητικούς αριθμούς, ενώ τα ποσά που εισπράττετε, όπως οι επιταγές μερισμάτων, αποδίδονται με θετικούς αριθμούς.

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	10%	Ετήσιο επιτόκιο
3	1	Περίοδος για την οποία θέλετε να υπολογίσετε τον τόκο
4	3	Έτη δανείου
5	8000	Παρούσα αξία του δανείου
6	Τύπος	Περιγραφή (αποτέλεσμα)
7	=IPMT(A2/12; A3*3; A4; A5)	Τόκος που καταβάλλεται τον πρώτο μήνα για ένα δάνειο, βάσει των παραπάνω όρων (-22,41)
8	=IPMT(A2; 3; A4; A5)	Τόκος που καταβάλλεται το τελευταίο έτος για ένα δάνειο, βάσει των παραπάνω όρων, όταν οι πληρωμές καταβάλλονται ετησίως (-292,45)

Σημείωση   Το επιτόκιο διαιρείται δια του 12, για τον υπολογισμό του μηνιαίου επιτοκίου. Τα έτη καταβολής του δανείου πολλαπλασιάζονται επί δώδεκα, για τον υπολογισμό του αριθμού των πληρωμών

IRR(values;guess)

Αποδίδει το συντελεστή εσωτερικής απόδοσης μίας σειράς ταμειακών ροών που αντιπροσωπεύονται από τα ποσά του πίνακα values. Οι ταμειακές ροές δεν χρειάζεται να είναι άρτιες, όπως θα συνέβαινε σε προσόδους. Ωστόσο, οι ταμειακές συναλλαγές πρέπει να λαμβάνουν χώρα σε τακτά διαστήματα, όπως σε μηνιαία ή ετήσια βάση. Ο συντελεστής εσωτερικής απόδοσης είναι το επιτόκιο που λαμβάνετε για μια επένδυση που περιλαμβάνει πληρωμές (αρνητικές τιμές του πίνακα values) και εισπράξεις (θετικές τιμές του πίνακα values), οι οποίες πραγματοποιούνται σε τακτά χρονικά διαστήματα.

Values   είναι πίνακας ή αναφορά κελιών που περιέχει αριθμούς (ποσά ταμειακών ροών), για τους οποίους θέλετε να υπολογίσετε το συντελεστή εσωτερικής απόδοσης.

• Το όρισμα values πρέπει να περιέχει τουλάχιστον μία θετική και μία αρνητική τιμή, για να μπορεί να υπολογιστεί ο συντελεστής εσωτερικής απόδοσης.
• Η συνάρτηση IRR χρησιμοποιεί τη διάταξη των τιμών στον πίνακα values, για να υπολογίσει τη διαδοχή των ταμειακών ροών. Βεβαιωθείτε ότι τα ποσά πληρωμών και εισπράξεων είναι καταχωρημένα με τη σειρά που θέλετε.
• Εάν ένα όρισμα πίνακα ή αναφοράς περιέχει κείμενο, λογικές τιμές ή κενά κελιά, οι τιμές αυτές παραβλέπονται.

Guess   είναι μια πρόβλεψη που κάνετε για το αποτέλεσμα της συνάρτησης IRR.

• Το Microsoft Excel χρησιμοποιεί επαναληπτική μέθοδο, για τον υπολογισμό του συντελεστή εσωτερικής απόδοσης. Αρχίζοντας με την τιμή του ορίσματος guess, η συνάρτηση IRR εκτελεί επαναληπτικούς υπολογισμούς, μέχρι το αποτέλεσμα να συγκλίνει με ακρίβεια της τάξης του 0,00001. Εάν η συνάρτηση IRR δεν μπορεί να συγκλίνει σε αποτέλεσμα μετά από 20 επαναλήψεις, αποδίδει την τιμή σφάλματος #ΑΡΙΘ!.
• Στις περισσότερες περιπτώσεις, δεν χρειάζεται να συμπεριλάβετε το όρισμα guess για τον υπολογισμό της συνάρτησης IRR. Εάν παραλειφθεί το όρισμα guess, θεωρείται ίσο με 0,1 (10 τοις εκατό).
• Εάν η συνάρτηση IRR αποδίδει την τιμή σφάλματος #ΑΡΙΘ! ή αν το αποτέλεσμα δεν είναι το αναμενόμενο, ξαναδοκιμάστε αλλάζοντας την τιμή του ορίσματος guess.

Παρατηρήσεις :

Η συνάρτηση IRR σχετίζεται με τη συνάρτηση NPV (καθαρής παρούσας αξίας). Ο συντελεστής εσωτερικής απόδοσης που υπολογίζεται από τη συνάρτηση IRR είναι ο συντελεστής, για τον οποίο μηδενίζεται η καθαρή παρούσα αξία. Ο παρακάτω τύπος παρουσιάζει τη σχέση των συναρτήσεων NPV και IRR: NPV(IRR(B1:B6);B1:B6) ίσον 3,60E-08 (Με την ακρίβεια υπολογισμού του συντελεστή εσωτερικής απόδοσης, η τιμή 3,60E-08 είναι πρακτικά 0.)

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	-70.000	Αρχικό κόστος μιας επιχείρησης
3	12.000	Καθαρό εισόδημα κατά το πρώτο έτος
4	15.000	Καθαρό εισόδημα κατά το δεύτερο έτος
5	18.000	Καθαρό εισόδημα κατά το τρίτο έτος
6	21.000	Καθαρό εισόδημα κατά το τέταρτο έτος
7	26.000	Καθαρό εισόδημα κατά το πέμπτο έτος
8	Τύπος	Περιγραφή (αποτέλεσμα)
9	=IRR(A2:A6)	Συντελεστής εσωτερικής απόδοσης της επένδυσης μετά από τέσσερα χρόνια (-2%)
10	=IRR(A2:A7)	Συντελεστής εσωτερικής απόδοσης μετά από πέντε χρόνια (9%)
11	=IRR(A2:A4;-10%)	Για να υπολογίσετε το συντελεστή εσωτερικής απόδοσης μετά από δύο χρόνια, πρέπει να συμπεριλάβετε μια πρόβλεψη (-44%)

ISPMT(rate;per;nper;pv)

Υπολογίζει τον τόκο που καταβλήθηκε σε μια συγκεκριμένη περίοδο μιας επένδυσης. Αυτή η συνάρτηση παρέχεται για συμβατότητα με το Lotus 1-2-3.

Rate   είναι το επιτόκιο της επένδυσης.

Per είναι η περίοδος για την οποία θέλετε να υπολογίσετε τον τόκο και πρέπει να είναι ανάμεσα στο 1 και στο nper.

Nper   είναι ο συνολικός αριθμός περιόδων πληρωμής της επένδυσης.

Pv   είναι η τρέχουσα αξία της επένδυσης. Για ένα δάνειο, pv είναι το ποσό του δανείου.

Παρατηρήσεις

• Βεβαιωθείτε για τη συνέπεια των μονάδων που χρησιμοποιούνται στις τιμές των ορισμάτων rate και nper. Εάν έχετε μηνιαίες δόσεις για τετραετές δάνειο με ετήσιο επιτόκιο 12 τοις εκατό, χρησιμοποιήστε 12%/12 για το όρισμα rate και 4*12 για το όρισμα nper. Εάν έχετε ετήσιες δόσεις για το ίδιο δάνειο, χρησιμοποιήστε 12% για το όρισμα rate και 4 για το όρισμα nper.
• Για όλα τα ορίσματα, τα μετρητά που δίνετε, όπως σε καταθέσεις αποταμίευσης ή άλλες αναλήψεις, αποδίδονται με αρνητικούς αριθμούς. Τα μετρητά που λαμβάνετε, όπως από επιταγές μερισμάτων και άλλες καταθέσεις, αποδίδονται με θετικούς αριθμούς.
• Για επιπλέον πληροφορίες σχετικά με οικονομικές συναρτήσεις, ανατρέξτε στη συνάρτηση PV.

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	10%	Ετήσιο επιτόκιο
3	1	Περίοδος
4	3	Αριθμός ετών της επένδυσης
5	8000000	Ποσό δανείου
6	Τύπος	Περιγραφή (αποτέλεσμα)
7	=ISPMT(A2/12;A3;A4*12;A5)	Τόκος που καταβάλλεται για την πρώτη μηνιαία πληρωμή ενός δανείου, βάσει των παραπάνω όρων (-64814,8)
8	=ISPMT(A2;1;A4;A5)	Τόκος που καταβάλλεται κατά το πρώτο έτος ενός δανείου, βάσει των παραπάνω όρων (-533333)

Σημείωση  Το επιτόκιο διαιρείται δια του 12, για τον υπολογισμό του μηνιαίου επιτοκίου. Ο αριθμός των ετών καταβολής του δανείου πολλαπλασιάζεται επί δώδεκα, για τον υπολογισμό του αριθμού των πληρωμών.

MIRR(values;finance_rate;reinvest_rate)

Values    είναι πίνακας ή αναφορά σε κελιά που περιέχουν αριθμούς. Οι αριθμοί αυτοί αντιπροσωπεύουν μια σειρά πληρωμών (αρνητικές τιμές) και εισοδημάτων (θετικές τιμές) σε τακτά χρονικά διαστήματα.

• Το όρισμα values πρέπει να περιέχει τουλάχιστον μία θετική και μία αρνητική τιμή, για να υπολογιστεί η τροποποιημένη εσωτερική απόδοση. Σε αντίθετη περίπτωση, η συνάρτηση MIRR αποδίδει την τιμή σφάλματος #ΔΙΑΙΡ/0!.
• Εάν κάποιο όρισμα πίνακα ή αναφοράς περιέχει κείμενο, λογικές τιμές ή κενά κελιά, οι τιμές αυτές παραβλέπονται. Ωστόσο, περιλαμβάνονται τα κελιά με τιμή μηδέν.

Finance_rate    είναι το επιτόκιο που καταβάλλετε για τα χρήματα που χρησιμοποιούνται στις ταμειακές ροές.

Reinvest_rate    είναι το επιτόκιο που λαμβάνετε από τις ταμειακές ροές, όταν τις επενδύετε εκ νέου.

Παρατηρήσεις

• Η συνάρτηση MIRR βασίζεται στη διάταξη των τιμών του ορίσματος values, για να υπολογίσει τη διαδοχή των ταμειακών ροών. Βεβαιωθείτε ότι τα ποσά πληρωμών και εισπράξεων είναι καταχωρημένα με τη σειρά που θέλετε και με τα σωστά πρόσημα (θετικές τιμές για ποσά που εισπράττετε και αρνητικές τιμές για ποσά που καταβάλλετε).
• Εάν n είναι ο αριθμός των ταμειακών ροών στο όρισμα values, frate είναι το όρισμα finance_rate και rrate είναι το όρισμα reinvest_rate, τότε ο τύπος για τη συνάρτηση MIRR είναι:

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	-120.000 Δρχ.	Αρχικό κόστος
3	39.000	Απόδοση κατά το πρώτο έτος
4	30.000	Απόδοση κατά το δεύτερο έτος
5	21.000	Απόδοση κατά το τρίτο έτος
6	37.000	Απόδοση κατά το τέταρτο έτος
7	46.000	Απόδοση κατά το πέμπτο έτος
8	10,00%	Ετήσιο επιτόκιο για το δάνειο των 120.000 Δρχ.
9	12,00%	Ετήσιο επιτόκιο για τα κέρδη που έχουν επενδυθεί εκ νέου
10	Τύπος	Περιγραφή (αποτέλεσμα)
11	=MIRR(A2:A7; A8; A9)	Τροποποιημένος συντελεστής απόδοσης της επένδυσης μετά από πέντε χρόνια (13%)
12	=MIRR(A2:A5; A8; A9)	Τροποποιημένος συντελεστής απόδοσης μετά από τρία χρόνια (-5%)
13	=MIRR(A2:A7; A8; 14%)	Πενταετής τροποποιημένος συντελεστής απόδοσης με επιτόκιο επενδύσεων 14 τοις εκατό (13%)

NPER(rate;pmt;pv;fv;type)

Αποδίδει το πλήθος των περιόδων μιας επένδυσης, με βάση περιοδικές σταθερές πληρωμές και σταθερό επιτόκιο.

Rate    είναι το επιτόκιο ανά περίοδο.

Pmt    είναι η πληρωμή που καταβάλλεται σε κάθε περίοδο και δεν μπορεί να αλλάξει κατά τη διάρκεια της προσόδου. Συνήθως, το όρισμα pmt περικλείει κεφάλαιο και επιτόκιο, αλλά όχι τέλη ή φόρους.

Pv    είναι η παρούσα αξία ή το εφάπαξ ποσό που αντιπροσωπεύει μια σειρά μελλοντικών πληρωμών σε τρέχουσες τιμές.

Fv    είναι η μελλοντική αξία ή το υπόλοιπο ταμείου που θέλετε να επιτύχετε αφού γίνει η τελευταία πληρωμή. Εάν παραλειφθεί το όρισμα fv, θεωρείται ίσο με 0 (η μελλοντική αξία ενός δανείου, για παράδειγμα, είναι 0).

Type    είναι ο αριθμός 0 ή 1 και επισημαίνει πότε πρέπει να καταβάλλονται οι πληρωμές.

Type	Πληρωμές
0 ή παράλειψη της τιμής	Στο τέλος της περιόδου
1	Στην αρχή της περιόδου

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	12%	Ετήσιο επιτόκιο
3	-100	Πληρωμή που καταβάλλεται σε κάθε περίοδο
4	-1000	Παρούσα αξία
5	10000	Μελλοντική αξία
6	1	Η πληρωμή καταβάλλεται στην αρχή της περιόδου (βλέπε παραπάνω)
7	Τύπος	Περιγραφή (αποτέλεσμα)
8	=NPER(A2/12; A3; A4; A5; 1)	Περίοδοι για την επένδυση με τους παραπάνω όρους (60)
9	=NPER(A2/12; A3; A4; A5)	Περίοδοι για την επένδυση με τους παραπάνω όρους, αλλά με καταβολή των πληρωμών στην αρχή της περιόδου (60)
10	=NPER(A2/12; A3; A4)	Περίοδοι για την επένδυση με τους παραπάνω όρους, αλλά με μηδενική μελλοντική αξία (-9,578)

NPV(rate;value1;value2; ...)

Αποδίδει την καθαρή παρούσα αξία μιας επένδυσης με βάση ένα προεξοφλητικό επιτόκιο και μια σειρά μελλοντικών πληρωμών (αρνητικές τιμές) και εισοδημάτων (θετικές τιμές).

Rate   είναι το προεξοφλητικό επιτόκιο κατά τη διάρκεια μίας περιόδου.

Value1, value2,...    είναι 1 έως 29 ορίσματα που αντιπροσωπεύουν πληρωμές και εισοδήματα.

• Οι συναλλαγές των ορισμάτων value1, value2,... πρέπει να απέχουν ίσα χρονικά διαστήματα και να πραγματοποιούνται στο τέλος κάθε περιόδου.
• Η συνάρτηση NPV χρησιμοποιεί τη διάταξη των ορισμάτων value1, value2,... για να ερμηνεύσει τη διαδοχή των ταμειακών ροών. Βεβαιωθείτε ότι η καταχώρηση των ποσών πληρωμών και εισοδημάτων γίνεται με τη σωστή σειρά.
• Υπολογίζονται τα ορίσματα που είναι αριθμοί, κενά κελιά, λογικές τιμές ή κείμενο που αντιπροσωπεύει αριθμούς. Τα ορίσματα που είναι τιμές σφαλμάτων ή κείμενο που δεν μετατρέπεται σε αριθμούς παραβλέπονται.
• Εάν ένα όρισμα είναι πίνακας ή αναφορά, τότε υπολογίζονται μόνο οι αριθμοί αυτού του πίνακα ή της αναφοράς. Τα κενά κελιά, οι λογικές τιμές, το κείμενο ή οι τιμές σφάλματος που υπάρχουν στον πίνακα ή την αναφορά παραβλέπονται.

Παρατηρήσεις

• Η επένδυση NPV αρχίζει μία περίοδο πριν από την ημερομηνία της ταμειακής ροής του ορίσματος value1 και λήγει με την τελευταία ταμειακή ροή της λίστας. Ο υπολογισμός της συνάρτησης NPV βασίζεται σε μελλοντικές ταμειακές ροές. Εάν η πρώτη συναλλαγή πραγματοποιηθεί στην αρχή της πρώτης περιόδου, η πρώτη τιμή πρέπει να προστεθεί στο αποτέλεσμα της NPV και να μην περιληφθεί στα ορίσματα των τιμών. Για περισσότερες πληροφορίες, ανατρέξτε στα παρακάτω παραδείγματα.
• Εάν n είναι ο αριθμός των ταμειακών ροών στη λίστα των τιμών, ο τύπος για τη συνάρτηση NPV είναι:

• Η συνάρτηση NPV είναι παρόμοια με τη συνάρτηση PV (παρούσας αξίας). Η βασική διαφορά ανάμεσα στην PV και την NPV είναι ότι η PV επιτρέπει την πραγματοποίηση ταμειακών ροών στο τέλος ή στην αρχή της περιόδου. Σε αντίθεση με τις μεταβλητές τιμές των ταμειακών ροών της NPV, οι ταμειακές ροές της PV πρέπει να είναι σταθερές σε όλη τη διάρκεια της επένδυσης. Για πληροφορίες σχετικά με προσόδους και οικονομικές συναρτήσεις, ανατρέξτε στη συνάρτηση PV.
• Η συνάρτηση NPV σχετίζεται επίσης με τη συνάρτηση IRR (συντελεστή εσωτερικής απόδοσης). Η συνάρτηση IRR αποδίδει το συντελεστή, για τον οποίο η συνάρτηση NPV ισούται με μηδέν: NPV(IRR(...); ...)=0.

Παράδειγμα 1 :

	A	B
1	Δεδομένα	Περιγραφή
2	10%	Ετήσιο προεξοφλητικό επιτόκιο
3	-10.000	Αρχικό κόστος της επένδυσης ένα χρόνο μετά τη σημερινή ημέρα
4	3.000	Απόδοση κατά το πρώτο έτος
5	4.200	Απόδοση κατά το δεύτερο έτος
6	6.800	Απόδοση κατά το τρίτο έτος
7	Τύπος	Περιγραφή (αποτέλεσμα)
8	=NPV(A2; A3; A4; A5; A6)	Καθαρή παρούσα αξία αυτής της επένδυσης (1.188,44)

Στο παράδειγμα, το αρχικό κόστος των 10.000 Δρχ. περιλαμβάνεται στις τιμές, γιατί η πληρωμή γίνεται στο τέλος της πρώτης περιόδου.

Παράδειγμα 2 :

	A	B
1	Δεδομένα	Περιγραφή
2	8%	Ετήσιο προεξοφλητικό επιτόκιο. Ο συντελεστής αυτός μπορεί να αντιπροσωπεύει τον πληθωρισμό ή το επιτόκιο μιας ανταγωνιστικής επένδυσης.
3	-40.000	Αρχικό κόστος της επένδυσης
4	8.000	Απόδοση κατά το πρώτο έτος
5	9.200	Απόδοση κατά το δεύτερο έτος
6	10.000	Απόδοση κατά το τρίτο έτος
7	12.000	Απόδοση κατά το τέταρτο έτος
8	14.500	Απόδοση κατά το πέμπτο έτος
9	Τύπος	Περιγραφή (αποτέλεσμα)
10	=NPV(A2; A4:A8)+A3	Καθαρή παρούσα αξία αυτής της επένδυσης (1.922,06)
11	=NPV(A2; A4:A8; -9000)+A3	Καθαρή παρούσα αξία αυτής της επένδυσης, με ζημία 9000 Δρχ. κατά το έκτο έκτος (-3.749,47)

Στο παράδειγμα, δεν περιλαμβάνεται στις τιμές το αρχικό κόστος των 40.000 Δρχ., γιατί η πληρωμή γίνεται στην αρχή της πρώτης περιόδου.

PMT(rate;nper;pv;fv;type)

Αποδίδει το ποσό της δόσης ενός δανείου με βάση σταθερές πληρωμές και σταθερό επιτόκιο.

Rate    είναι το επιτόκιο ενός δανείου.

Nper    είναι το συνολικό πλήθος πληρωμών του δανείου.

Pv    είναι η παρούσα αξία ή το συνολικό ποσό στο οποίο ανέρχεται αυτή τη στιγμή μια σειρά μελλοντικών πληρωμών, γνωστό και ως αρχικό κεφάλαιο.

Fv    είναι η μελλοντική αξία ή το υπόλοιπο ταμείου που θέλετε να επιτύχετε μετά την καταβολή της τελευταίας πληρωμής. Εάν παραλειφθεί το όρισμα fv, θεωρείται ίσο με 0 (μηδέν), δηλαδή η μελλοντική αξία ενός δανείου είναι 0.

Type    είναι ο αριθμός 0 ή 1 και επισημαίνει πότε πρέπει να καταβάλλονται οι πληρωμές.

Type	Πληρωμές
0 ή παράλειψη της τιμής	Στο τέλος της περιόδου
1	Στην αρχή της περιόδου

Παρατηρήσεις

• Το ποσό της δόσης που αποδίδει η συνάρτηση PMT περιλαμβάνει αρχικό κεφάλαιο και επιτόκιο, αλλά όχι φόρους, εγγυήσεις ή τέλη που σχετίζονται μερικές φορές με δάνεια.
• Βεβαιωθείτε για τη συνέπεια των μονάδων που χρησιμοποιούνται στις τιμές των ορισμάτων rate και nper. Εάν έχετε μηνιαίες δόσεις για τετραετές δάνειο με ετήσιο επιτόκιο 12 τοις εκατό, χρησιμοποιήστε 12%/12 για το όρισμα rate και 4*12 για το όρισμα nper. Εάν έχετε ετήσιες δόσεις για το ίδιο δάνειο, χρησιμοποιήστε 12% για το όρισμα rate και 4 για το όρισμα nper.

Για να υπολογίσετε το συνολικό ποσό που καταβλήθηκε κατά τη διάρκεια του δανείου, πολλαπλασιάστε την επιστρεφόμενη τιμή της συνάρτησης PMT με τον αριθμό των περιόδων του ορίσματος nper.

Παράδειγμα 1 :

	A	B
1	Δεδομένα	Περιγραφή
2	8%	Ετήσιο επιτόκιο
3	10	Αριθμός μηνιαίων πληρωμών
4	1000000	Ποσό δανείου
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=PMT(A2/12; A3; A4)	Μηνιαία πληρωμή για ένα δάνειο με τους παραπάνω όρους (-103.703)
7	=PMT(A2/12; A3; A4; 0; 1)	Μηνιαία πληρωμή για ένα δάνειο με τους παραπάνω όρους, αλλά με καταβολή των πληρωμών στην αρχή της περιόδου (-103.016,43)

Μπορείτε να χρησιμοποιήσετε τη συνάρτηση PMT, για να καθορίσετε πληρωμές σε προσόδους που δεν αφορούν δάνεια.

Παράδειγμα 2 :

	A	B
1	Δεδομένα	Περιγραφή
2	6%	Ετήσιο επιτόκιο
3	18	Προγραμματισμένα έτη αποταμίευσης
4	5.000.000	Ποσό που θέλετε να αποταμιεύσετε σε 18 χρόνια
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=PMT(A2/12; A3*12; 0; A4)	Ποσό που πρέπει να αποταμιεύετε κάθε μήνα, για να έχετε 5.000.000 στο τέλος των 18 ετών (-12.908)

Σημείωση  Το επιτόκιο διαιρείται δια του 12, για τον υπολογισμό του μηνιαίου επιτοκίου. Ο αριθμός των ετών καταβολής των χρημάτων πολλαπλασιάζεται επί δώδεκα, για τον υπολογισμό του αριθμού των πληρωμών.

PPMT(rate;per;nper;pv;fv;type)

Αποδίδει το ποσό αποπληρωμής του αρχικού κεφαλαίου μιας επένδυσης σε μια δεδομένη περίοδο, με βάση περιοδικές, σταθερές πληρωμές και σταθερό επιτόκιο.

Rate    είναι το επιτόκιο ανά περίοδο.

Per    καθορίζει την περίοδο και πρέπει να κυμαίνεται ανάμεσα στο 1 και στο nper.

Nper    είναι ο συνολικός αριθμός των περιόδων πληρωμής μιας προσόδου.

Pv είναι η παρούσα αξία ή το εφάπαξ ποσό που αντιπροσωπεύει μια σειρά μελλοντικών πληρωμών σε τρέχουσες τιμές.

Fv   είναι η μελλοντική αξία ή το υπόλοιπο ταμείου που θέλετε να έχετε μετά την καταβολή της τελευταίας πληρωμής. Εάν παραλειφθεί το όρισμα fv, θεωρείται ίσο με 0 (μηδέν), δηλαδή η μελλοντική αξία ενός δανείου είναι 0.

Type    είναι ο αριθμός 0 ή 1 και επισημαίνει πότε πρέπει να καταβάλλονται οι πληρωμές.

Type	Πληρωμές
0 ή παράλειψη της τιμής	Στο τέλος της περιόδου
1	Στην αρχή της περιόδου

Παρατήρηση

Βεβαιωθείτε για τη συνέπεια των μονάδων που χρησιμοποιούνται στις τιμές των ορισμάτων rate και nper. Εάν κάνετε μηνιαίες πληρωμές για ένα τετραετές δάνειο με 12 τοις εκατό ετήσιο επιτόκιο, χρησιμοποιήστε το 12%/12 για το όρισμα rate και το 4*12 για το όρισμα nper. Εάν κάνετε ετήσιες πληρωμές για το ίδιο δάνειο, χρησιμοποιήστε το 12% για το όρισμα rate και το 4 για το όρισμα nper.

Παράδειγμα 1 :

	A	B
1	Δεδομένα	Περιγραφή (αποτέλεσμα)
2	10%	Ετήσιο επιτόκιο
3	2	Αριθμός ετών του δανείου
4	200000	Ποσό δανείου
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=PPMT(A2/12; 1; A3*12; A4)	Αποπληρωμή κεφαλαίου για τον πρώτο μήνα ενός δανείου (-7.562,32)

Σημείωση   Το επιτόκιο διαιρείται δια του 12, για τον υπολογισμό του μηνιαίου επιτοκίου. Ο αριθμός των ετών καταβολής των χρημάτων πολλαπλασιάζεται επί δώδεκα, για τον υπολογισμό του αριθμού των πληρωμών.

Παράδειγμα 2 :

	A	B
1	Δεδομένα	Περιγραφή (αποτέλεσμα)
2	8%	Ετήσιο επιτόκιο
3	10	Αριθμός ετών του δανείου
4	20.000.000	Ποσό δανείου
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=PPMT(A2; A3; 10; A4)	Αποπληρωμή κεφαλαίου για το τελευταίο έτος του δανείου, με τους παραπάνω όρους (-2.759.805,35)

PV(rate;nper;pmt;fv;type)

Αποδίδει την παρούσα αξία μιας επένδυσης. Η παρούσα αξία είναι το εφάπαξ ποσό που αντιπροσωπεύει μια σειρά μελλοντικών πληρωμών σε τρέχουσες τιμές. Για παράδειγμα, όταν δανείζεστε χρήματα, το ποσό του δανείου αποτελεί για το δανειστή την παρούσα αξία.

Rate   είναι το επιτόκιο ανά περίοδο. Για παράδειγμα, αν πάρετε ένα καταναλωτικό δάνειο με ετήσιο επιτόκιο 10% και καταβάλετε μηνιαίες δόσεις, το μηνιαίο επιτόκιο είναι 10%/12 ή 0,83%. Θα έπρεπε να καταχωρήσετε στον τύπο την τιμή 10%/12 ή 0,83% ή 0,0083, για το όρισμα rate.

Nper    είναι ο συνολικός αριθμός των περιόδων πληρωμής μιας προσόδου. Για παράδειγμα, αν πάρετε ένα τετραετές καταναλωτικό δάνειο και καταβάλετε μηνιαίες δόσεις, το δάνειο έχει 4*12 (ή 48) περιόδους. Θα έπρεπε να καταχωρήσετε στον τύπο την τιμή 48 για το όρισμα nper.

Pmt    είναι η πληρωμή που καταβάλλεται σε κάθε περίοδο και δεν μπορεί να αλλάξει κατά τη διάρκεια της προσόδου. Συνήθως το όρισμα pmt περιλαμβάνει κεφάλαιο και επιτόκιο, αλλά όχι τέλη ή φόρους. Για παράδειγμα, οι μηνιαίες πληρωμές για ένα τετραετές καταναλωτικό δάνειο 1.000.000 Δρχ. με 12% επιτόκιο είναι 26.333 Δρχ. Θα έπρεπε να καταχωρήσετε την τιμή -26333 για το όρισμα pmt. Εάν παραλείψετε το όρισμα pmt, πρέπει να συμπεριλάβετε το όρισμα fv.

Fv   είναι η μελλοντική αξία ή το υπόλοιπο που θέλετε να έχετε μετά την καταβολή της τελευταίας πληρωμής. Εάν παραλειφθεί το όρισμα fv, θεωρείται ίσο με 0 (η μελλοντική αξία ενός δανείου, για παράδειγμα, είναι 0). Για παράδειγμα, αν θέλετε να αποταμιεύσετε 5.000.000 Δρχ. για κάτι που σχεδιάζετε να κάνετε σε 18 χρόνια, τότε το ποσό των 5.000.000 Δρχ. αποτελεί τη μελλοντική αξία. Θα μπορούσατε να κάνετε μια συντηρητική πρόβλεψη για το επιτόκιο και να προσδιορίσετε πόσα χρήματα πρέπει να αποταμιεύετε μηνιαίως. Εάν παραλείψετε το όρισμα fv, πρέπει να συμπεριλάβετε το όρισμα pmt.

Type    είναι ο αριθμός 0 ή 1 και επισημαίνει πότε πρέπει να καταβάλλονται οι πληρωμές.

Type	Πληρωμές
0 ή παράλειψη της τιμής	Στο τέλος της περιόδου
1	Στην αρχή της περιόδου

Παρατηρήσεις

• Βεβαιωθείτε για τη συνέπεια των μονάδων που χρησιμοποιούνται στις τιμές των ορισμάτων rate και nper. Εάν κάνετε μηνιαίες πληρωμές για ένα τετραετές δάνειο με 12 τοις εκατό ετήσιο επιτόκιο, χρησιμοποιήστε το 12%/12 για το όρισμα rate και το 4*12 για το όρισμα nper. Εάν κάνετε ετήσιες πληρωμές για το ίδιο δάνειο, χρησιμοποιήστε το 12% για το όρισμα rate και το 4 για το όρισμα nper.
• Οι παρακάτω συναρτήσεις εφαρμόζονται σε προσόδους:

CUMIPMT	PPMT
CUMPRINC	PV
FV	RATE
FVSCHEDULE	XIRR
IPMT	XNPV
PMT

• Πρόσοδος είναι μια σειρά σταθερών ταμειακών πληρωμών για μια συνεχή περίοδο. Για παράδειγμα, ένα καταναλωτικό δάνειο ή μια υποθήκη αποτελεί πρόσοδο. Για περισσότερες πληροφορίες, ανατρέξτε στην περιγραφή των συναρτήσεων που σχετίζονται με προσόδους.
• Σε συναρτήσεις προσόδων, τα χρήματα που καταβάλλετε, όπως οι καταθέσεις που κάνετε, αποδίδονται με αρνητικούς αριθμούς, ενώ τα χρήματα που εισπράττετε, όπως τα μερίσματα, αποδίδονται με θετικούς αριθμούς. Για παράδειγμα, μια κατάθεση 100.000 Δρχ. σε λογαριασμό τραπέζης αντιστοιχεί στην τιμή -100000 για τον καταθέτη και στην τιμή 100000 για την τράπεζα.
• Το Microsoft Excel συσχετίζει κατά την επίλυση τα οικονομικά ορίσματα.
• Εάν το όρισμα rate δεν είναι 0, τότε:

o Εάν το όρισμα rate είναι 0, τότε: (pmt * nper) + pv + fv = 0

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	50000	Χρήματα που καταβάλλονται για ασφάλιστρα στο τέλος κάθε μήνα
3	8%	Επιτόκιο που κερδίζεται για τα καταβαλλόμενα χρήματα
4	20	Έτη αποπληρωμής των χρημάτων
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=PV(A3/12; 12*A4; A2; ; 0)	Παρούσα αξία μιας προσόδου με τους παραπάνω όρους (-5.977.715).

Το αποτέλεσμα είναι αρνητικός αριθμός, γιατί αντιπροσωπεύει καταβλητέο ποσό χρημάτων, δηλαδή ταμειακή εκροή. Εάν σας ζητηθεί να καταβάλλετε (6.000.000) για την πρόσοδο, θα διαπιστώνατε ότι είναι ασύμφορη επένδυση, εφόσον η παρούσα αξία της προσόδου (5.977.715) είναι μικρότερη από το ποσό που σας ζητείται.

Σημείωση  Το επιτόκιο διαιρείται δια του 12, για τον υπολογισμό του μηνιαίου επιτοκίου. Τα έτη καταβολής των χρημάτων πολλαπλασιάζονται επί δώδεκα, για τον υπολογισμό του αριθμού των πληρωμών.

RATE(nper;pmt;pv;fv;type;guess)

Αποδίδει το επιτόκιο μιας προσόδου ανά περίοδο. Η συνάρτηση RATE υπολογίζεται με επαναληπτική μέθοδο και μπορεί να μην έχει λύση ή να έχει αρκετές λύσεις. Εάν οι διαδοχικές επιλύσεις της συνάρτησης RATE δεν συγκλίνουν με ακρίβεια της τάξης του 0,0000001, μετά από 20 διαδοχικές προσεγγίσεις, τότε η συνάρτηση RATE αποδίδει την τιμή σφάλματος #ΑΡΙΘ!.

Nper    είναι ο συνολικός αριθμός των περιόδων πληρωμής μιας προσόδου.

Pmt    είναι η πληρωμή που καταβάλλεται σε κάθε περίοδο και δεν μπορεί να αλλάξει κατά τη διάρκεια της προσόδου. Συνήθως, το όρισμα pmt περιλαμβάνει κεφάλαιο και επιτόκιο, αλλά όχι τέλη ή φόρους. Εάν παραλείψετε το όρισμα pmt, πρέπει να συμπεριλάβετε το όρισμα fv.

Pv    είναι η παρούσα αξία ή το εφάπαξ ποσό που αντιπροσωπεύει μια σειρά μελλοντικών πληρωμών σε τρέχουσες τιμές.

Fv είναι η μελλοντική αξία ή το υπόλοιπο που θέλετε να έχετε μετά την καταβολή της τελευταίας πληρωμής. Εάν παραλειφθεί το όρισμα fv, θεωρείται ίσο με 0 (η μελλοντική αξία ενός δανείου, για παράδειγμα, είναι 0).

Type    είναι ο αριθμός 0 ή 1 και επισημαίνει πότε πρέπει να καταβάλλονται οι πληρωμές.

Type	Πληρωμές
0 ή παράλειψη της τιμής	Στο τέλος της περιόδου
1	Στην αρχή της περιόδου

Guess είναι η πρόβλεψή σας για το επιτόκιο.

• Εάν παραλειφθεί το όρισμα guess, θεωρείται ίσο με 10%.
• Εάν η συνάρτηση RATE δεν συγκλίνει, δοκιμάστε διαφορετικές τιμές για το όρισμα guess. Η συνάρτηση RATE συνήθως συγκλίνει, όταν το όρισμα guess έχει τιμή μεταξύ 0 και 1.

Παρατήρηση

Βεβαιωθείτε για τη συνέπεια των μονάδων που χρησιμοποιούνται στις τιμές των ορισμάτων guess και nper. Εάν έχετε μηνιαίες δόσεις για τετραετές δάνειο με ετήσιο επιτόκιο 12 τοις εκατό, χρησιμοποιήστε 12%/12 για το όρισμα guess και 4*12 για το όρισμα nper. Εάν έχετε ετήσιες δόσεις για το ίδιο δάνειο, χρησιμοποιήστε 12% για το όρισμα guess και 4 για το όρισμα nper.

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	4	Έτη δανείου
3	-20000	Μηνιαία πληρωμή
4	800000	Ποσό δανείου
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=RATE(A2*12; A3; A4)	Μηνιαίο επιτόκιο του δανείου με τους παραπάνω όρους (1%)
7	=RATE(A2*12; A3; A4)*12	Ετήσιο επιτόκιο του δανείου με τους παραπάνω όρους (0,09241767 ή 9,24%)

Σημείωση  Ο αριθμός των ετών του δανείου πολλαπλασιάζεται επί δώδεκα, για τον υπολογισμό του αριθμού των μηνών.

SLN(cost;salvage;life)

Αποδίδει τη σταθερή απόσβεση ενός παγίου, σε μια χρονική περίοδο.

Cost    είναι το αρχικό κόστος του παγίου.

Salvage    είναι η τελική αξία του παγίου, αφού ολοκληρωθεί η απόσβεσή του (μερικές φορές αναφέρεται ως υπολειμματική αξία του παγίου).

Life είναι ο συνολικός χρόνος απόσβεσης του παγίου (μερικές φορές αναφέρεται ως ωφέλιμος χρόνος ζωής του παγίου).

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	3.000.000	Κόστος
3	750.000	Υπολειμματική αξία
4	10	Ωφέλιμος χρόνος ζωής
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=SLN(A2; A3; A4)	Η απόσβεση για κάθε έτος (225.000)

SYD(cost;salvage;life;per)

Αποδίδει την απόσβεση παγίου σε συγκεκριμένη χρονική περίοδο, βάσει του αθροίσματος των ετών απόσβεσης.

Cost είναι το αρχικό κόστος του παγίου.

Salvage    είναι η τελική αξία του παγίου, αφού ολοκληρωθεί η απόσβεσή του (μερικές φορές αναφέρεται ως υπολειμματική αξία του παγίου).

Life    είναι ο συνολικός χρόνος απόσβεσης του παγίου (μερικές φορές αναφέρεται ως ωφέλιμος χρόνος ζωής του παγίου).

Per   είναι η χρονική περίοδος απόσβεσης και πρέπει να χρησιμοποιεί τις ίδιες μονάδες με το όρισμα life.

Παρατήρηση

• Η συνάρτηση SYD υπολογίζεται ως εξής:

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	3.000.000	Αρχικό κόστος
3	750.000	Υπολειμματική αξία
4	10	Έτη ωφέλιμης ζωής
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=SYD(A2;A3;A4;1)	Ετήσια απόσβεση για το πρώτο έτος (409.091)
7	=SYD(A2;A3;A4;10)	Ετήσια απόσβεση για το δέκατο έτος (40.909)

VDB(cost;salvage;life;start_period;end_period;factor;no_switch)

Αποδίδει την απόσβεση ενός πάγιου για καθορισμένη περίοδο, συμπεριλαμβανομένου τμήματος περιόδου, χρησιμοποιώντας τη μέθοδο του διπλά φθίνοντος υπολοίπου ή άλλη μέθοδο που θα καθορίσετε. Το όνομα της συνάρτησης σημαίνει το μεταβλητά φθίνον υπόλοιπο (Variable Declining Balance ή VDB).

Cost   είναι το αρχικό κόστος του παγίου.

Salvage    είναι η τελική αξία του παγίου, αφού ολοκληρωθεί η απόσβεσή του (μερικές φορές αναφέρεται ως υπολειμματική αξία του παγίου).

Life    είναι ο συνολικός χρόνος απόσβεσης του παγίου (μερικές φορές αναφέρεται ως ωφέλιμος χρόνος ζωής του παγίου).

Start_period    είναι η πρώτη περίοδος του διαστήματος, για το οποίο θέλετε να υπολογίσετε την απόσβεση. Το όρισμα start_period πρέπει να χρησιμοποιεί τις ίδιες μονάδες με το όρισμα life.

End_period    είναι η τελευταία περίοδος του διαστήματος, για το οποίο θέλετε να υπολογίσετε την απόσβεση. Το όρισμα end_period πρέπει να χρησιμοποιεί τις ίδιες μονάδες με το όρισμα life.

Factor    είναι ο συντελεστής του φθίνοντος υπολοίπου. Εάν παραλειφθεί το όρισμα factor, θεωρείται ίσο με 2 (μέθοδος του διπλά φθίνοντος υπολοίπου). Αλλάξτε το όρισμα factor, αν δεν θέλετε να χρησιμοποιήσετε αυτήν τη μέθοδο. Για περιγραφή της μεθόδου του διπλά φθίνοντος υπολοίπου, ανατρέξτε στη συνάρτηση DDB.

No_switch    είναι μια λογική τιμή, που καθορίζει αν η συνάρτηση θα χρησιμοποιήσει σταθερή απόσβεση, όταν η απόσβεση γίνει μεγαλύτερη από το φθίνον υπόλοιπο.

• Εάν το όρισμα no_switch είναι TRUE (αληθές), τότε το Microsoft Excel δεν θα χρησιμοποιήσει σταθερή απόσβεση, ακόμα και όταν η απόσβεση γίνει μεγαλύτερη από το φθίνον υπόλοιπο.
• Εάν το όρισμα no_switch είναι FALSE (ψευδές) ή παραλείπεται, τότε το Excel θα χρησιμοποιήσει σταθερή απόσβεση, όταν η απόσβεση γίνει μεγαλύτερη από το φθίνον υπόλοιπο.

Όλα τα ορίσματα εκτός από το no_switch πρέπει να είναι θετικοί αριθμοί.

Παράδειγμα :

	A	B
1	Δεδομένα	Περιγραφή
2	240000	Αρχικό κόστος
3	30000	Υπολειμματική αξία
4	10	Διάρκεια ζωής σε έτη
5	Τύπος	Περιγραφή (αποτέλεσμα)
6	=VDB(A2; A3; A4*365; 0; 1)	Η απόσβεση της πρώτης ημέρας. Το Excel θεωρεί αυτόματα ότι ο συντελεστής είναι 2 (131,51)
7	=VDB(A2; A3; A4*12; 0; 1)	Η απόσβεση του πρώτου μήνα (4.000,00)
8	=VDB(A2; A3; A4; 0; 1)	Η απόσβεση του πρώτου έτους (48.000,00)
9	=VDB(A2; A3; A4*12; 6; 18)	Η απόσβεση μεταξύ του έκτου και του δέκατου όγδοου μήνα (39.630,61)
10	=VDB(A2; A3; A4*12; 6; 18; 1,5)	Η απόσβεση μεταξύ του έκτου και του δέκατου όγδοου μήνα, χρησιμοποιώντας το συντελεστή 1,5, αντί της μεθόδου του διπλά φθίνοντος υπολοίπου (31.180,89)
11	=VDB(A2; A3; A4; 0; 0,875; 1,5)	Η απόσβεση για το πρώτο οικονομικό έτος κατοχής του πάγιου, με την προϋπόθεση ότι η φορολογική νομοθεσία δεν επιτρέπει την απόσβεση του φθίνοντος υπολοίπου σε ποσοστό μεγαλύτερο του 150%. Η αγορά του παγίου γίνεται στο μέσον του πρώτου τριμήνου του οικονομικού έτους. (31.500,00)

Σημείωση  Τα αποτελέσματα στρογγυλοποιούνται σε δύο δεκαδικά ψηφία.